5. 絶縁とそのドライバ/レシーバ

★　この、[SIM.X.Y] の欄は、シミュレーションに関する詳細な解説です。シミュレーションに関心がある読者、とくに自分でシミュレーションを行いたい読者は読んでください。シミュレーションそのものには、興味が無い読者は、この[SIM.X.Y] 欄を読み飛ばすと良いでしょう(以降も同じ)。

★　シミュレーションのプログラムは、*.cir ファイルです。この講座では、シミュレーションプログラムは、原則として本文の図と対になっています。したがって、シミュレーションプログラムのファイル名は、対になる図番号と対比できる名称にしてあります。たとえば、ここに示すプログラムは、図.8(fg8.gif)に対応していますから、fg5_8.cir です。
★　シミュレーションプログラムのリストをLIST.5.8に示します(リスト番号も、同様に揃えてあります)。

[LIST.5.8]

    fg5_8 trans sag and rebound

    .tran   100n   20u    ; トランジェント解析

    .step param l  list 6m 600u 200u 60u
    .param  l=6m
    vp      1   0   pwl(0,0)(1U,0)(1.01U,3)(5U,3)(5.01U,0)
  
    r1     1    2    10
    l1     2    0    {l}
    r2     2    0    100
    .probe
    .end

★　以下に概要を解説します。デバイスやコマンドの一覧が、PSICEインデックスにあります。デバイスやコマンドの詳細な解説は、講座「自動制御」にあり、PSICEインデックスから、リンクすることができます。
★　*.cir プログラムの、最初の 1 行は、コメントです。この最初の行のコメントは、特殊な役割を持っています。
★　3 行目(見やすくするために空行を入れてありますから、実質的には 2 行目です) : .tran は、解析の種類が、トランジェント解析(コマンド .tran)であることを示します。最初の数字 100n は、解析のプリント・ステップ値、次の 20u は、解析の終了時間を示します。なお、*.cir ファイルでは、ギリシャ文字は使えませんから、u はマイクロを意味します。
★; 以下はコメントです。この ; で始まるコメントは、行の途中から、それ以降をコメントとする場合に使用します。このリストでは使っていませんが、行頭からコメントの場合は、行頭に * を入れます。
★　7 行目の　v はデバイス 電圧源です(p は、デバイス v の番号です。番号は、この例のように、数字でなく文字を使用することができます)。電圧源には幾つかの種類があります。この電圧源は、pwl と呼ばれる種類の電圧源です。
★　pwl は、折れ線による任意波形の電圧を発生します。ここでは、1 発のパルスを作っています。折れ点を、時刻と電圧値の組で与えます。たとえば、最初の組(0,0)は、時刻ゼロで電圧がゼロであることを、次の(1U,0)は、時刻 1μsのとき電圧がゼロであることを示します。当然、時刻順に並べなければなりません。記述した最後の組以降は、その最後電圧値が持続します。
★　vp の次にある数字、1 と 0 とは、ノードです。ノードは、回路の配線接続を表わします。この例では、電圧源 vp は、ノード 1 と、ノード 0 とに接続されています。ノード 0 は、常にグラウンドを表わします。
★　9 行目 r は、デバイス 抵抗です。次の 2 つの数字はノードです。ノード 1 は、電圧源 vp にもありますから、相互に配線されていることを示します。3 番目の数字は、抵抗の値です。11 行目の r2 も抵抗です。
★　10 行目 l はデバイス インダクタです。次の 2 つの数字は、抵抗と同様にノードです。その次が、インダクタンス値を示します。ただし、ここは数字ではなくて文字になっています。数学で、数値を文字で代表させるように、PSPICE でも、文字やさらには式で表わすことができます。ただし、PSPICE では、リストに示してあるように、数値を文字または式で表わしているときは、それらを { } に入れなければなりません。
★　6 行目 数値を文字で表わしたときは、その数値を別のところで指定する必要があります(文字のままで、数値が示されなければ、計算はできません)。この数値を指定するコマンドが、.param です。ここでは、文字 l を l=6m として、指定しています。この場合は、インダクタですから、単位は H (ヘンリー)です。インダクタであれは、H に決まっていますから、単位記号 H を記述する必要はありません。ただし、書いてもエラーにはなりません。書くかどうかは、好みの問題です。この講座では、単位記号は書きません。
★　ここに書いてある m　は補助単位の「ミリ」です。補助単位の書き方は、自動制御 2.1.5.表.2-1-2 にあります。間違いやすいので注意しなければならないのは、ミリ(m) とメガ(mega) です。PSPICE では、大文字と小文字が区別されませんから、M は m と同じで「ミリ」です。そして、メガは、MEG または meg です。
★　5 行目 .step は、数値を変えてケーススタディを行うためのコマンドです。その結果は、図.8 に示されている通りです。1回の*.cir の演算で、パラメータ値を変えた、複数の演算を行います。そして、1 つの図に表示されます。.param と .step は、PSPICE を使用する上で、きわめて有効なコマンドです。
.step コマンドを使用したとき、.step の対象となる .param コマンドの値(この例では、l=6)は無視されて、.step の list に示された値が使用されます。しかし、.param における値の指定を省略することはできません。

★　回路ファイル fg5_12.cir のリストを LIST.5.12 に示します。この回路ファイルは、以降多くのprobe 画面を作りますが、回路ファイルの命名法にしたがって、以下の最初の probe 画面の図番号を取って名を付けてあります。

[LIST.5.12]

    fg5_12	transient resoanse  for  simple line  with transformer

    .TRAN  20N   40U  0   20n    uic          ; トランジェント解析の指定

    VP1    1    0    PWL(0,0)(1U,0)(1.01U,1)(5U,1)(5.01U,0)(9U,0)
    +(9.01U,-1)(13U,-1)(13.01U,0)(17U,0)(17.01U,1)(21U,1)(21.01U,0)
    +(25U,0)(25.01U,-1)(29U,-1)(29.01U,0)     ; 信号波形の指定

    .step   param   lt   list   1k   6m  ; ケーススタディのためのコマンド
    .param  lt=6m
    .param  rl=1g
    rs      1       in      100
    lt1     in      0       {lt}
    rl1     in      0       {rl}
    xline   in      out     line   params:   len=400
    rl2     out     0       {rl}
    rlt     out     0       100
    lt2     out     0       {lt}
    .subckt         lin     in     out
    xln     in      out     mult   params:  lg4=1
    .ends

    .subckt         mul     in     out
    xmult   in      out     cpev601
    .ends

    .lib    "..\dtran.lib"

    .probe
    .end

★　このモデルは、基本的には fg4_17 と同じです。それにトランスおよび抵抗負荷を追加したものです。また、ケーススタディのための .step コマンドが追加されています。

ダウンロード fg5_12.cir